"LNGS"4#v(0"dedaol LNGS :DOOG">:#,_$a,   v
        >0"dedaol ton LNGS :DAB">:#,_$a,@
v                                        <
>"ENGS"4#v(0"dedaol ENGS :DOOG">:#,_$a,   v
         >0"dedaol ton ENGS :DAB">:#,_$a,@
v                                         <
>0"sdnoces 01 rof peels lliw .peels gnitseT :OFNI">:#,_$a,v
v                                                         <
>37*ya#vL37*y\-0"pu ekow L :DOOG">:#,_$a,              v
       >0"langis a thguac ro detcelfer L :DAB">:#,_$a,@
v    ; v      <  < ;                                   <
>:a-#v_>0"emit fo tnuoma thgir eht rof tpels L taht sraeppA :DOOG">:#,_$a,v
     >:9-#v_  ^
          >:b-#v_^
v              <
>0" :emit fo tnuoma gnorw eht rof tpels L sraeppA :DAB">:#,_$.a,@
v                                                                         <
>#vI:00p0" :ssecorp siht fo DIP :OFNI">:#,_$.a,v
v                                              <
>0a2*e#vH0"MRLAGIS rof reldnah langis dellatsnI :OFNI">:#,_$a,       v
v      >0"MRLAGIS rof reldnah langis llatsni ot deliaF :DAB">:#,_$a,@
>0"MRLAGIS thguaC :DOOG">:#,_$a,v
v                               <
>37*y10p@

v                                                                    <
>0"sdnoces 01 rof mrala tes ot A esu lliW :OFNI">:#,_$a,v
v                                                       <
>37*ya#vA0"mrala eht tes ot deraeppa A :DOOG">:#,_$a,$v
       >0"mrala gnittes detcelfer A :DAB">:#,_$a,@
v                                                     <
>0"thguac mrala litnu gnisuaP :OFNI">:#,_$a,v
v                                           <
>#vPaa*>: v
       ^-1_$  v
  >0"detcelfer P :DAB">:#,_$a,@
v             <
>10g'L-#v_0"krow ton did P taht sraeppA :DAB">:#,_$a,@
        >0"tiaw did P taht sraeppA :DOOG">:#,_$a,v
v                                                <
>10g\-0" :)01 fo 2 ro dnoces a nihtiw eb dluohs( detiaw emiT :OFNI">:#,_$.a,v
v                                                                           <
>0"01 rof reldnah langis gnillatsnI :OFNI">:#,_$a,0a4*3+aH     v
>0"thguac 01 langiS :DOOG">:#,_$a,v
v                                 <
>a-#v_0"thguac saw 01 langis wohs did kcatS :DOOG">:#,_$a,  v
    >0"thguac 01 langis wohs ton seod kcatS :DAB">:#,_$a,v
v                                              ;v        <; <
>00g-#v_0"tcerroc si kcats no DIP :DOOG">:#,_$a,> '>6a5*3+p@
      >0"gnorw si kcats no DIP :DAB">:#,_$a,    ^
v                                                              <
>0"fles ot 01 langis dnes ot S gnisU :OFNI">:#,_$a,v
v                                                  <
>a#vS><0"pool dekcolnu reldnah langiS :DOOG">:#,_$a,v
   >0"01 langis gnidnes detcelfer S :DAB">:#,_$a,@
v                                                   <
>0"T htiw margorp etanimret lliW :OFNI">:#,_$a,v
v                                              <
>#vT0"margorp eht etanimret ot raeppa ton did T :DAB">:#,_$a,@
  >0"detcelfer T :DAB">:#,_$a,@


Expected Output:
----------------
GOOD: SGNL loaded
GOOD: SGNE loaded
INFO: Testing sleep. will sleep for 10 seconds
GOOD: L woke up
GOOD: Appears that L slept for the right amount of time
INFO: PID of this process: 29790 
INFO: Installed signal handler for SIGALRM
INFO: Will use A to set alarm for 10 seconds
GOOD: A appeared to set the alarm
INFO: Pausing until alarm caught
GOOD: Caught SIGALRM
GOOD: Appears that P did wait
INFO: Time waited (should be within a second or 2 of 10): 10 
INFO: Installing signal handler for 10
INFO: Using S to send signal 10 to self
GOOD: Signal 10 caught
GOOD: Stack did show signal 10 was caught
GOOD: PID on stack is correct
GOOD: Signal handler unlocked loop
INFO: Will terminate program with T
Aborted